home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 23 / CU Amiga - Super CD-ROM 23 (June 1998).iso / CreatingGames / Utilities / Asm / AB3DIIsrc / source_4000 / abreed3.lha / ObjectMovea < prev    next >
Encoding:
Text File  |  1995-09-09  |  29.2 KB  |  2,150 lines
  1. extlen: dc.w 0
  2. awayfromwall: dc.w 0
  3. wallbounce: dc.w 0
  4. wallxsize: dc.w 0
  5. wallzsize: dc.w 0
  6. walllength: dc.w 0
  7.  
  8. RoomPath: ds.w 100
  9. RoomPathPtr: dc.l 0
  10.  
  11. MoveObject:
  12.  
  13.  move.l #RoomPath,RoomPathPtr
  14.  
  15.  clr.b hitwall
  16.  
  17.  move.w newx,d0
  18.  sub.w oldx,d0
  19.  move.w d0,xdiff
  20.  move.w newz,d0
  21.  sub.w oldz,d0
  22.  move.w d0,zdiff
  23.  
  24.  move.l newy,wallhitheight
  25.  move.l objroom,a0
  26.  
  27. gobackanddoitallagain:
  28.  
  29.  move.l a0,a5
  30.  adda.w ToExitList(a5),a0
  31.  move.l a0,test
  32.  move.l FloorLines,a1
  33. checkwalls:
  34.  move.w (a0)+,d0
  35.  blt nomorewalls
  36.  
  37.  asl.w #4,d0
  38.  lea (a1,d0.w),a2
  39.  
  40. *********************************
  41. * Check if we are within exit limits
  42. * of zone.
  43. *********************************
  44.  
  45.  move.l #-65536*256,d0
  46.  move.l d0,LowerRoofHeight
  47.  move.l d0,UpperRoofHeight
  48.  move.l d0,LowerFloorHeight
  49.  move.l d0,UpperFloorHeight
  50.  
  51. ; tst.b 9(a2)
  52. ; bne thisisawall2
  53.  
  54.  moveq #0,d1
  55.  move.w 8(a2),d1
  56.  blt thisisawall2
  57.  move.l ZoneAdds,a4
  58.  move.l (a4,d1.w*4),a4
  59.  add.l LEVELDATA,a4
  60.  
  61.  move.l ToZoneFloor(a4),d1
  62.  move.l d1,LowerFloorHeight
  63.  move.l ToZoneRoof(a4),d2
  64.  move.l d2,LowerRoofHeight
  65.  sub.l d2,d1
  66.  cmp.l thingheight,d1
  67.  ble thisisawall1
  68.  
  69.  move.l oldy,d0
  70.  move.l d0,d1
  71.  add.l thingheight,d1
  72.  sub.l ToZoneFloor(a4),d1
  73.  bgt.s chkstepup
  74.  
  75.  neg.l d1
  76.  cmp.l StepDownVal,d1
  77.  blt.s botinsidebot
  78.  
  79. chkstepup:
  80.  cmp.l StepUpVal,d1
  81.  blt.s botinsidebot
  82.  
  83. ; We have a wall!
  84.  bra thisisawall1
  85.  
  86. botinsidebot:
  87.  
  88.  sub.l ToZoneRoof(a4),d0
  89.  blt.s thisisawall1
  90.  
  91.  bra checkwalls
  92.  
  93. thisisawall1:
  94.  
  95.  move.l ToUpperFloor(a4),d1
  96.  move.l d1,UpperFloorHeight
  97.  move.l ToUpperRoof(a4),d2
  98.  sub.l d2,d1
  99.  move.l d2,UpperRoofHeight
  100.  cmp.l thingheight,d1
  101.  ble thisisawall2
  102.  
  103.  move.l oldy,d0
  104.  move.l d0,d1
  105.  add.l thingheight,d1
  106.  sub.l ToUpperFloor(a4),d1
  107.  bgt.s chkstepup2
  108.  
  109.  neg.l d1
  110.  cmp.l StepDownVal,d1
  111.  blt.s botinsidebot2
  112.  bra.s thisisawall2
  113.  
  114. chkstepup2:
  115.  cmp.l StepUpVal,d1
  116.  blt.s botinsidebot2
  117.  
  118. ; We have a wall!
  119.  bra thisisawall2
  120.  
  121. botinsidebot2:
  122.  
  123.  sub.l ToUpperRoof(a4),d0
  124.  blt.s thisisawall2
  125.  
  126.  bra checkwalls
  127. thisisawall2
  128.  
  129.  move.l #0,a4
  130.  move.l #0,a6
  131.  move.b awayfromwall,d3
  132.  blt.s .notomatoes
  133.  
  134.  move.b 12(a2),d2
  135.  ext.w d2
  136.  
  137.  move.b 13(a2),d4
  138.  ext.w d4
  139.  
  140.  tst.b d3
  141.  beq.s .noshift
  142.  asl.w d3,d2
  143.  asl.w d3,d4
  144. .noshift
  145.  
  146.  move.w d2,a4
  147.  move.w d4,a6
  148.  
  149. .notomatoes:
  150.  
  151.  move.w newx,d0
  152.  move.w newz,d1
  153.  sub.w (a2),d0
  154.  sub.w 2(a2),d1
  155.  sub.w a4,d0
  156.  sub.w a6,d1
  157.  
  158.  move.w 4(a2),d2
  159.  sub.w a4,d2
  160.  sub.w a6,d2
  161.  
  162.  muls d2,d1
  163.  
  164.  move.w 6(a2),d5
  165.  add.w a4,d5
  166.  sub.w a6,d5
  167.  
  168.  muls d5,d0
  169.  sub.l d1,d0
  170.  blt chkhttt
  171.  
  172.  move.w 10(a2),d3
  173.  add.w extlen,d3
  174.  divs d3,d0
  175.  cmp.w #32,d0
  176.  bge oknothitwall
  177.  
  178.  move.w wallflags(pc),d0
  179.  or.w d0,14(a2) 
  180.  
  181.  bra oknothitwall
  182.  
  183. chkhttt:
  184.  
  185.  move.w d2,WALLXLEN
  186.  move.w d5,WALLZLEN
  187.  
  188.  move.l d0,d7
  189.  
  190.  move.w 10(a2),d3
  191.  add.w extlen,d3
  192.  divs d3,d7    ;  d
  193.  
  194.  move.l newy,d4
  195.  sub.l oldy,d4
  196. ; beq .dontworryhit
  197.  
  198.  move.w oldx,d0
  199.  move.w oldz,d1
  200.  sub.w (a2),d0
  201.  sub.w 2(a2),d1
  202.  sub.w a4,d0
  203.  sub.w a6,d1
  204.  
  205.  muls d2,d1
  206.  muls d5,d0
  207.  sub.l d1,d0
  208.  divs d3,d0    ; otherd
  209.  
  210.  sub.w d7,d0    ; total distance travelled across wall
  211.  bgt.s .ohbugger
  212.  moveq #1,d0
  213. .ohbugger:
  214.  
  215. ; We now have ratio to multiply x,z and y differences
  216. ; by. Check y=0 since that's quite common.
  217.  
  218.  move.l d4,d1
  219.  beq.s .dontworryhit
  220.  
  221.  divs d0,d1
  222.  muls d7,d1
  223. .dontworryhit:
  224.  add.l newy,d1 ; height at point of crossing wall.
  225.  move.l d1,d6
  226.  add.l thingheight,d6
  227.  
  228.  cmp.l LowerFloorHeight,d6
  229.  bge.s .yeshit
  230.  cmp.l LowerRoofHeight,d1
  231.  bgt oknothitwall
  232.  cmp.l UpperRoofHeight,d1
  233.  blt.s .yeshit
  234.  cmp.l UpperFloorHeight,d6
  235.  blt oknothitwall
  236.  
  237. .yeshit:
  238.  
  239.  move.l d1,wallhitheight
  240.  
  241.  tst.b wallbounce
  242.  bne.s .calcbounce
  243.  
  244.  tst.b exitfirst(pc)
  245.  beq.s .calcalong
  246.  bne.s .calcwherehit
  247.  
  248. .calcbounce:
  249.  
  250. ; For simplicity (possibility!) the
  251. ; bounce routine will:
  252. ; Place the object at wall contact
  253. ; point
  254. ; Supply wall data to reflect the
  255. ; movement direction of the object
  256.  
  257.  move.w d2,wallxsize
  258.  move.w d5,wallzsize
  259.  move.w d3,walllength
  260.  
  261. .calcwherehit:
  262.  
  263. ; add.w #20,d7
  264.  move.w newx,d6
  265.  sub.w oldx,d6
  266.  muls d7,d6
  267.  divs d0,d6
  268.  add.w newx,d6
  269.  
  270.  move.w newz,d1
  271.  sub.w oldz,d1
  272.  muls d7,d1
  273.  divs d0,d1
  274.  add.w newz,d1
  275.  move.w d6,d0
  276.  move.w d1,d7
  277.  bra.s .calcedhit
  278.  
  279. .calcalong:
  280.  
  281. ; sub.w #3,d7
  282.  move.w d7,d6
  283.  muls d5,d6
  284.  muls d2,d7
  285.  divs d3,d6
  286.  divs d3,d7
  287.  neg.w d6
  288.  add.w newx,d6    ; point on wall
  289.  add.w newz,d7
  290.  
  291.  move.w d6,d0
  292.  move.w d7,d1
  293. ; bra.s othercheck
  294.  
  295. .calcedhit:
  296.  
  297. ; move.w newx,d6
  298. ; move.w newz,d7
  299. ; sub.w oldx,d6
  300. ; sub.w oldz,d7
  301. ;  
  302. ; move.w (a2),d4
  303. ; add.w a4,d4
  304. ; sub.w oldx,d4
  305. ; muls d4,d7; negative if on left
  306. ; move.w 2(a2),d4
  307. ; add.w a6,d4
  308. ; sub.w oldz,d4
  309. ; muls d4,d6
  310. ; sub.l d6,d7
  311. ; bgt oknothitwall
  312. ; 
  313. ;; move.w d0,d6
  314. ;; move.w d1,d7
  315. ; move.w newx,d6
  316. ; move.w newz,d7
  317. ; sub.w oldx,d6
  318. ; sub.w oldz,d7
  319. ; 
  320. ; move.w (a2),d4
  321. ; add.w d2,d4
  322. ; sub.w oldx,d4
  323. ; muls d4,d7; negative if on left
  324. ; move.w 2(a2),d4
  325. ; add.w d5,d4
  326. ; sub.w oldz,d4
  327. ; muls d4,d6
  328. ; sub.l d6,d7
  329. ; blt oknothitwall
  330. ; bra hitthewall
  331. ;
  332.  
  333.  move.w (a2),d0
  334.  add.w a4,d0
  335.  sub.w oldx,d0    ; a-e
  336.  move.w newz,d1
  337.  sub.w oldz,d1    ; h-f
  338.  muls d1,d0        ; (a-e)*(h-f)
  339.  
  340.  move.w newx,d2
  341.  sub.w oldx,d2    ; g-e
  342.  
  343.  move.w 2(a2),d3
  344.  add.w a6,d3
  345.  sub.w oldz,d3    ; b-f
  346.  muls d2,d3        ; (g-e)*(b-f)
  347.  sub.l d3,d0        ; (a-e)*(h-f)-(g-e)*(b-f)
  348. ; beq oknothitwall
  349.  
  350.  muls WALLZLEN,d2
  351.  muls WALLXLEN,d1
  352.  sub.l d1,d2
  353.  beq oknothitwall
  354.  
  355.  tst.l d0
  356.  bge.s .toppos
  357.  tst.l d2
  358.  bgt oknothitwall
  359.  cmp.l d0,d2
  360.  bgt oknothitwall
  361.  move.w d6,d0
  362.  move.w d7,d1
  363.  bra hitthewall
  364.  
  365. .toppos
  366.  tst.l d2
  367.  blt oknothitwall
  368.  cmp.l d0,d2
  369.  blt oknothitwall
  370.  move.w d6,d0
  371.  move.w d7,d1
  372.  bra hitthewall
  373.  
  374. othercheck:
  375.  
  376. ; sub.w (a2),d6
  377. ; sub.w 2(a2),d7
  378. ; sub.w a4,d6
  379. ; sub.w a6,d7
  380. ; 
  381. ; muls d6,d6
  382. ; muls d7,d7
  383. ; add.w #5,d3
  384. ; muls d3,d3
  385. ; 
  386. ; add.l d6,d7
  387. ; cmp.l d3,d7
  388. ; bgt oknothitwall
  389. ; 
  390. ; move.w d1,d7
  391. ; move.w d0,d6
  392. ; sub.w (a2),d6
  393. ; sub.w 2(a2),d7
  394. ; sub.w d2,d6
  395. ; sub.w d5,d7
  396. ; muls d6,d6
  397. ; muls d7,d7
  398. ; add.l d6,d7
  399. ; cmp.l d3,d7
  400. ; bgt oknothitwall
  401. ; 
  402. ;************8 
  403.  
  404.  sub.w (a2),d6
  405.  sub.w 2(a2),d7
  406.  
  407.  sub.w a4,d6
  408.  sub.w a6,d7
  409.  move.w d2,d4
  410.  bge.s okplus1
  411.  neg.w d4
  412. okplus1
  413.  move.w d5,d3
  414.  bge.s okplus2
  415.  neg.w d3
  416. okplus2:
  417.  cmp.w d4,d3
  418.  bgt.s UseZ
  419.  
  420. ; Use the x coord!
  421.  
  422.  tst.w d6
  423.  bgt.s xispos
  424.  
  425.  move.w d2,d7
  426.  cmp.w #4,d7
  427.  bgt.s oknothitwall
  428.  sub.w #4,d7
  429.  cmp.w d7,d6
  430.  blt.s oknothitwall
  431.  
  432.  bra.s hitthewall
  433.  
  434. xispos:
  435.  
  436.  move.w d2,d7
  437.  cmp.w #-4,d7
  438.  blt.s oknothitwall
  439.  add.w #4,d7
  440.  cmp.w d7,d6
  441.  bgt.s oknothitwall
  442.  
  443.  bra.s hitthewall
  444.  
  445. UseZ:
  446.  tst.w d7
  447.  bgt.s zispos
  448.  
  449.  move.w d5,d6
  450.  cmp.w #4,d6
  451.  bgt.s oknothitwall
  452.  sub.w #4,d6
  453.  cmp.w d6,d7
  454.  blt.s oknothitwall
  455.  
  456.  bra.s hitthewall
  457.  
  458. zispos:
  459.  
  460.  move.w d5,d6
  461.  cmp.w #-4,d6
  462.  blt.s oknothitwall
  463.  add.w #4,d6
  464.  cmp.w d6,d7
  465.  bgt.s oknothitwall 
  466.  
  467. hitthewall:
  468.  
  469.  move.w d0,newx
  470.  move.w d1,newz
  471.  move.w wallflags(pc),d0
  472.  or.w d0,14(a2)
  473.  st hitwall
  474.  tst.b exitfirst(pc)
  475.  bne stopandleave
  476.  
  477. oknothitwall:
  478.  
  479.  bra checkwalls
  480. nomorewalls:
  481.  
  482.  tst.w extlen
  483.  beq NOOTHERWALLSNEEDED
  484.  
  485.  tst.w xdiff
  486.  bne.s notstill
  487.  tst.w zdiff
  488.  bne.s notstill
  489.  move.l objroom,a0
  490.  bra mustbeinsameroom
  491. notstill:
  492.  
  493.  move.l a5,a0
  494.  add.w ToExitList(a0),a0
  495.  
  496. checkotherwalls:
  497.  move.w (a0)+,d0
  498.  bge anotherwalls
  499.  cmp.w #-2,d0
  500.  beq nomoreotherwalls
  501.  bra checkotherwalls
  502.  
  503. anotherwalls:
  504.  
  505.  asl.w #4,d0
  506.  lea (a1,d0.w),a2
  507.  
  508. *********************************
  509. * Check if we are within exit limits
  510. * of zone.
  511. *********************************
  512.  
  513. ; tst.b 9(a2)
  514. ; bne .thisisawall2
  515.  
  516.  moveq #0,d1
  517.  move.w 8(a2),d1
  518.  blt .thisisawall2
  519.  move.l ZoneAdds,a4
  520.  move.l (a4,d1.w*4),a4
  521.  add.l LEVELDATA,a4
  522.  
  523.  move.l ToZoneFloor(a4),d1
  524.  sub.l ToZoneRoof(a4),d1
  525.  cmp.l thingheight,d1
  526.  ble .thisisawall1
  527.  
  528.  move.l newy,d0
  529.  move.l d0,d1
  530.  add.l thingheight,d1
  531.  sub.l ToZoneFloor(a4),d1
  532.  bgt.s .chkstepup
  533.  
  534.  neg.l d1
  535.  cmp.l StepDownVal,d1
  536.  blt.s .botinsidebot
  537.  bra.s .thisisawall1
  538.  
  539. .chkstepup:
  540.  
  541.  cmp.l StepUpVal,d1
  542.  blt.s .botinsidebot
  543.  
  544. ; We have a wall!
  545.  bra .thisisawall1
  546.  
  547. .botinsidebot:
  548.  
  549.  sub.l ToZoneRoof(a4),d0
  550.  blt.s .thisisawall1
  551.  
  552.  bra checkotherwalls
  553.  
  554. .thisisawall1:
  555.  
  556.  move.l ToUpperFloor(a4),d1
  557.  sub.l ToUpperRoof(a4),d1
  558.  cmp.l thingheight,d1
  559.  ble .thisisawall2
  560.  
  561.  move.l newy,d0
  562.  move.l d0,d1
  563.  add.l thingheight,d1
  564.  sub.l ToUpperFloor(a4),d1
  565.  bgt.s .chkstepup2
  566.  
  567.  neg.l d1
  568.  cmp.l StepDownVal,d1
  569.  blt.s .botinsidebot2
  570.  bra.s .thisisawall2
  571.  
  572. .chkstepup2:
  573.  
  574.  cmp.l StepUpVal,d1
  575.  blt.s .botinsidebot2
  576.  
  577. ; We have a wall!
  578.  bra .thisisawall2
  579.  
  580. .botinsidebot2:
  581.  
  582.  sub.l ToUpperRoof(a4),d0
  583.  blt.s .thisisawall2
  584.  
  585.  bra checkotherwalls
  586.  
  587. .thisisawall2:
  588.  
  589.  move.l #0,a4
  590.  move.l #0,a6
  591.  move.b awayfromwall,d3
  592.  blt.s .notomatoes
  593.  
  594.  move.b 12(a2),d2
  595.  ext.w d2
  596.  
  597.  move.b 13(a2),d4
  598.  ext.w d4
  599.  
  600.  tst.b d3
  601.  beq.s .noshift
  602.  asl.w d3,d2
  603.  asl.w d3,d4
  604. .noshift
  605.  
  606.  move.w d2,a4
  607.  move.w d4,a6
  608.  
  609. .notomatoes:
  610.  
  611.  move.w 4(a2),d2
  612.  sub.w a4,d2
  613.  sub.w a6,d2
  614.  move.w d2,DX
  615.  move.w 6(a2),d5
  616.  add.w a4,d5
  617.  sub.w a6,d5
  618.  
  619.  
  620.  move.w newx,d0
  621.  move.w newz,d1
  622.  sub.w (a2),d0
  623.  sub.w 2(a2),d1
  624.  sub.w a4,d0
  625.  sub.w a6,d1
  626.  muls DX,d1
  627.  muls d5,d0
  628.  sub.l d1,d0
  629.  bge .oknothitwall
  630.  move.l d0,d7
  631.  
  632.  move.w oldx,d1
  633.  move.w newx,d3
  634.  sub.w d1,d3
  635.  sub.w (a2),d1
  636.  sub.w a4,d1 ;e-a=d1
  637.  
  638.  move.w 2(a2),d2
  639.  add.w a6,d2
  640.  sub.w oldz,d2    ;b-f=d2
  641.  
  642.  move.w newz,d4
  643.  sub.w oldz,d4
  644.  
  645.  muls d4,d1
  646.  muls d3,d2
  647.  add.l d2,d1    ; h(e-a)+g(b-f)
  648.  
  649.  muls DX,d4
  650.  muls d5,d3
  651.  sub.l d3,d4
  652.  beq .oknothitwall
  653.  bgt.s .botpos
  654. .botneg:
  655.  tst.l d1
  656.  bgt .oknothitwall
  657.  cmp.l d1,d4
  658.  ble .mighthit
  659.  bra .oknothitwall
  660.  
  661. .botpos:
  662.  tst.l d1
  663.  blt .oknothitwall
  664.  cmp.l d1,d4
  665.  blt .oknothitwall
  666.  
  667. .mighthit:
  668.  
  669.  move.w 10(a2),d0
  670.  add.w extlen,d0
  671.  divs d0,d7    ;  d
  672.  sub.w #3,d7
  673.  move.w d7,d6
  674.  muls d5,d6
  675.  muls DX,d7
  676.  divs d0,d6
  677.  divs d0,d7
  678.  neg.w d6
  679.  add.w newx,d6    ; point on wall
  680.  add.w newz,d7
  681.  
  682.  move.w oldx,d0
  683.  move.w oldz,d1
  684.  sub.w (a2),d0
  685.  sub.w 2(a2),d1
  686.  sub.w a4,d0
  687.  sub.w a6,d1
  688.  muls DX,d1
  689.  muls d5,d0
  690.  sub.l d1,d0
  691.  blt .oknothitwall
  692.  
  693.  move.w d6,d0
  694.  move.w d7,d1
  695.  
  696.  bra .hitthewall
  697.  
  698.  sub.w (a2),d6
  699.  sub.w 2(a2),d7
  700.  move.w d6,d4
  701.  bge.s .okplus1
  702.  neg.w d4
  703. .okplus1
  704.  move.w d7,d3
  705.  bge.s .okplus2
  706.  neg.w d3
  707. .okplus2:
  708.  cmp.w d4,d3
  709.  bgt.s .UseZ
  710.  
  711. ; Use the x coord!
  712.  
  713.  tst.w d6
  714.  bgt.s .xispos
  715.  
  716.  move.w DX,d7
  717.  bgt.s .oknothitwall
  718.  cmp.w d7,d6
  719.  blt.s .oknothitwall
  720.  
  721.  bra.s .hitthewall
  722.  
  723. .xispos:
  724.  
  725.  move.w DX,d7
  726.  blt.s .oknothitwall
  727.  cmp.w d7,d6
  728.  bgt.s .oknothitwall
  729.  
  730.  bra.s .hitthewall
  731.  
  732. .UseZ:
  733.  tst.w d7
  734.  bgt.s .zispos
  735.  
  736.  move.w d5,d6
  737.  bgt.s .oknothitwall
  738.  cmp.w d6,d7
  739.  blt.s .oknothitwall
  740.  
  741.  bra.s .hitthewall
  742.  
  743. .zispos:
  744.  
  745.  move.w d5,d6
  746.  blt.s .oknothitwall
  747.  cmp.w d6,d7
  748.  bgt.s .oknothitwall
  749.  
  750.  
  751. .hitthewall:
  752.  
  753.  move.w d0,newx
  754.  move.w d1,newz
  755.  move.w wallflags(pc),d0
  756.  or.w d0,14(a2)
  757.  st hitwall
  758.  tst.b exitfirst(pc)
  759.  bne stopandleave
  760.  
  761. .oknothitwall:
  762.  
  763.  bra checkotherwalls
  764. nomoreotherwalls:
  765.  
  766. NOOTHERWALLSNEEDED
  767.  
  768.  
  769. ; move.w xdiff,d2
  770. ; muls d2,d2
  771. ; move.w zdiff,d3
  772. ; muls d3,d3
  773. ; move.w #0,movespd
  774. ; move.l #0,largespd
  775. ; add.l d3,d2
  776. ;
  777. ; move.w #31,d0
  778. ;.findhigh
  779. ; btst d0,d2
  780. ; bne .foundhigh
  781. ; dbra d0,.findhigh
  782. ;.foundhigh
  783. ; asr.w #1,d0
  784. ; clr.l d3
  785. ; bset d0,d3
  786. ; move.l d3,d0
  787. ;
  788. ; move.w d0,d3
  789. ; muls d3,d3    ; x*x
  790. ; sub.l d2,d3    ; x*x-a
  791. ; asr.l #1,d3    ; (x*x-a)/2
  792. ; divs d0,d3    ; (x*x-a)/2x
  793. ; sub.w d3,d0    ; second approx
  794. ; bgt .stillnot0
  795. ; move.w #1,d0
  796. ;.stillnot0
  797. ;
  798. ; move.w d0,d3
  799. ; muls d3,d3
  800. ; sub.l d2,d3
  801. ; asr.l #1,d3
  802. ; divs d0,d3
  803. ; sub.w d3,d0    ; second approx
  804. ; bgt .stillnot02
  805. ; move.w #1,d0
  806. ;.stillnot02
  807. ;
  808. ; move.w d0,movespd
  809. ;.moving
  810. ; ext.l d0
  811. ; asl.l #5,d0
  812. ; move.l d0,largespd
  813.  
  814. *****************************************************
  815. * FIND ROOM WE'RE STANDING IN ***********************
  816. *****************************************************
  817.  
  818.  move.l a5,a0
  819.  adda.w ToExitList(a5),a0
  820.  
  821.  move.l FloorLines,a1
  822. CheckMoreFloorLines
  823.  move.w (a0)+,d0    ; Either a floor line or -1
  824.  blt NoMoreFloorLines
  825.  asl.w #4,d0
  826.  lea (a1,d0.w),a2
  827.  
  828.  tst.w 8(a2)
  829.  blt.s CheckMoreFloorLines
  830.  
  831.  clr.b CrossIntoTop
  832.  
  833.  moveq #0,d1
  834.  move.w 8(a2),d1
  835.  move.l ZoneAdds,a4
  836.  move.l (a4,d1.w*4),a4
  837.  add.l LEVELDATA,a4
  838.  
  839.  move.l newy,d0
  840.  move.l d0,d1
  841.  add.l thingheight,d1
  842.  
  843.  sub.l ToZoneRoof(a4),d0
  844.  blt.s NOTINLOWER
  845.  
  846.  sub.l ToZoneFloor(a4),d1
  847.  blt.s okthebottom
  848.  
  849.  cmp.l StepUpVal,d1
  850.  bgt.s NOTINLOWER
  851.  
  852. ; move.l ToZoneFloor(a4),d1
  853. ; sub.l thingheight,d1
  854. ; move.l d1,newy
  855.  bra okthebottom
  856.  
  857. NOTINLOWER:
  858.  
  859.  move.l ToZoneRoof(a4),billy
  860.  move.l ToZoneRoof(a4),billy+4
  861.  add.l d0,billy+4
  862.  
  863.  st CrossIntoTop
  864.  move.l newy,d0
  865.  move.l d0,d1
  866.  add.l thingheight,d1
  867.  sub.l ToUpperRoof(a4),d0
  868.  blt CheckMoreFloorLines
  869.  
  870.  sub.l ToUpperFloor(a4),d1
  871.  blt.s okthebottom
  872.  
  873.  cmp.l StepUpVal,d1
  874.  bgt CheckMoreFloorLines
  875.  
  876. ; move.l ToUpperFloor(a4),d1
  877. ; sub.l thingheight,d1
  878. ; move.l d1,newy
  879.  
  880. okthebottom
  881.  
  882.  move.w newx,d0
  883.  move.w newz,d1
  884.  sub.w (a2),d0    ;a
  885.  sub.w 2(a2),d1    ;b
  886.  muls 4(a2),d1
  887.  muls 6(a2),d0
  888.  moveq #0,d3
  889.  move.w 8(a2),d3
  890.  move.l ZoneAdds,a3
  891.  move.l (a3,d3.w*4),a3
  892.  add.l LEVELDATA,a3
  893.  sub.l d1,d0
  894.  bge StillSameSide
  895.  
  896. * Player is now on the left side of this line.
  897. * Where was he before?
  898.  
  899. ; cmp.l a4,a5
  900. ; bne StillSameSide
  901.  
  902. ; move.w oldx,d0
  903. ; move.w oldz,d1
  904. ; sub.w (a2),d0    ;a
  905. ; sub.w 2(a2),d1    ;b
  906. ; muls 4(a2),d1
  907. ; muls 6(a2),d0
  908. ; sub.l d1,d0
  909. ; blt StillSameSide
  910. ; bra checkifcrossed
  911.  
  912. OnRightsideofline:
  913. * Player is now on the right side of the line.
  914. * Where was he last time?
  915.  
  916. ; exg a3,a4
  917.  
  918. ; cmp.l a3,a5
  919. ; bne StillSameSide
  920.  
  921. ; move.w oldx,d0
  922. ; move.w oldz,d1
  923. ; sub.w (a2),d0    ;a
  924. ; sub.w 2(a2),d1    ;b
  925. ; muls 4(a2),d1
  926. ; muls 6(a2),d0
  927. ; sub.l d1,d0
  928. ; bgt StillSameSide
  929.  
  930. checkifcrossed:
  931.  
  932. *Player used to be on other side of this line.
  933. *Need to check if he crossed it.
  934.  
  935.  move.w (a2),d0
  936.  sub.w oldx,d0    ; a-e
  937.  move.w newz,d1
  938.  sub.w oldz,d1    ; h-f
  939.  muls d1,d0        ; (a-e)*(h-f)
  940.  
  941.  move.w newx,d2
  942.  sub.w oldx,d2    ; g-e
  943.  
  944.  move.w 2(a2),d3
  945.  sub.w oldz,d3    ; b-f
  946.  muls d2,d3        ; (g-e)*(b-f)
  947.  sub.l d3,d0        ; (a-e)*(h-f)-(g-e)*(b-f)
  948.  beq StillSameSide
  949.  
  950.  muls 6(a2),d2
  951.  muls 4(a2),d1
  952.  sub.l d1,d2
  953.  beq StillSameSide
  954.  
  955.  tst.l d0
  956.  bge.s .toppos
  957.  tst.l d2
  958.  bgt.s StillSameSide
  959.  cmp.l d0,d2
  960.  bgt.s StillSameSide
  961.  move.l a3,a5
  962.  move.l RoomPathPtr,a0
  963.  move.w (a3),(a0)+
  964.  move.l a0,RoomPathPtr
  965.  move.l a3,a0
  966.  move.b CrossIntoTop,StoodInTop
  967.  
  968.  
  969.  bra gobackanddoitallagain
  970.  bra.s donefloorline
  971.  
  972. .toppos
  973.  tst.l d2
  974.  blt.s StillSameSide
  975.  cmp.l d0,d2
  976.  blt.s StillSameSide
  977.  move.l a3,a5
  978.  move.l RoomPathPtr,a0
  979.  move.w (a3),(a0)+
  980.  move.l a0,RoomPathPtr
  981.  move.l a3,a0
  982.  move.b CrossIntoTop,StoodInTop
  983.  bra gobackanddoitallagain
  984.  
  985. StillSameSide:
  986. donefloorline:
  987.  
  988.  bra CheckMoreFloorLines
  989. NoMoreFloorLines:
  990.  
  991.  move.l a5,a0
  992.  move.l a5,objroom
  993.  
  994. mustbeinsameroom:
  995.  
  996. stopandleave:
  997.  
  998.  move.l RoomPathPtr,a0
  999.  move.w #-1,(a0)+
  1000.  
  1001.  rts
  1002.  
  1003.  
  1004. DX: dc.w 0
  1005.  
  1006. tstxval: dc.l 0
  1007. oldx: dc.l 0
  1008. oldz: dc.l 0
  1009. newx: dc.l 0
  1010. newz: dc.l 0
  1011. xdiff: dc.l 0
  1012. zdiff: dc.l 0
  1013. objroom: dc.l 0
  1014. hitwall: dc.b 0
  1015. exitfirst: dc.b 0
  1016. speed: dc.w 0
  1017. wallflags: dc.w 0
  1018. distaway: dc.w 0
  1019. newy: dc.l 0
  1020. oldy: dc.l 0
  1021. thingheight: dc.l 0
  1022. StepUpVal: dc.l 0
  1023. StepDownVal: dc.l 0
  1024. wallhitheight: dc.l 0
  1025. seclot: dc.b 0
  1026.  
  1027.  even
  1028. WALLXLEN: dc.w 0
  1029. WALLZLEN: dc.w 0
  1030. onwallx: dc.w 0
  1031. onwallz: dc.w 0
  1032. slidex: dc.w 0
  1033. slidez: dc.w 0
  1034. CrossIntoTop: dc.b 0
  1035. StoodInTop: dc.b 0
  1036. LowerFloorHeight: dc.l 0
  1037. LowerRoofHeight: dc.l 0
  1038. UpperFloorHeight: dc.l 0
  1039. UpperRoofHeight: dc.l 0
  1040.  
  1041. billy: dc.l 0,0
  1042.  
  1043.  even
  1044.  
  1045. HeadTowards:
  1046.  
  1047.  move.w newx,d1
  1048.  sub.w oldx,d1
  1049.  move.w d1,xdiff
  1050.  move.w newz,d2
  1051.  sub.w oldz,d2
  1052.  move.w d2,zdiff
  1053.  muls d1,d1
  1054.  muls d2,d2
  1055.  move.w #0,d0
  1056.  move.w d0,distaway
  1057.  add.l d1,d2
  1058.  beq nochange
  1059.  
  1060.  move.w #31,d0
  1061. .findhigh
  1062.  btst d0,d2
  1063.  bne .foundhigh
  1064.  dbra d0,.findhigh
  1065. .foundhigh
  1066.  asr.w #1,d0
  1067.  clr.l d3
  1068.  bset d0,d3
  1069.  move.l d3,d0
  1070.  
  1071.  move.w d0,d1
  1072.  muls d1,d1    ; x*x
  1073.  sub.l d2,d1    ; x*x-a
  1074.  asr.l #1,d1    ; (x*x-a)/2
  1075.  divs d0,d1    ; (x*x-a)/2x
  1076.  sub.w d1,d0    ; second approx
  1077.  bgt .stillnot0
  1078.  move.w #1,d0
  1079. .stillnot0
  1080.  
  1081.  move.w d0,d1
  1082.  muls d1,d1
  1083.  sub.l d2,d1
  1084.  asr.l #1,d1
  1085.  divs d0,d1
  1086.  sub.w d1,d0    ; second approx
  1087.  bgt .stillnot02
  1088.  move.w #1,d0
  1089. .stillnot02
  1090.  
  1091.  move.w d0,distaway
  1092.  
  1093. ; d0=perpdist
  1094.  
  1095.  cmp.w Range,d0
  1096.  sle GotThere
  1097.  bgt.s faraway
  1098.  
  1099.  move.w xdiff,d1
  1100.  move.w zdiff,d2
  1101.  muls Range,d1
  1102.  muls Range,d2
  1103.  divs d0,d1
  1104.  divs d0,d2
  1105.  neg.w d1
  1106.  neg.w d2
  1107.  add.w d1,newx
  1108.  add.w d2,newz
  1109.  tst.b canshove
  1110.  beq nochange
  1111.  move.w PLR1_opushx(pc),d1
  1112.  add.w PLR2_opushx(pc),d1
  1113.  sub.w d1,newx
  1114.  move.w PLR1_opushz(pc),d1
  1115.  add.w PLR2_opushz(pc),d1
  1116.  sub.w d1,newz
  1117.  move.w xdiff,d1
  1118.  move.w zdiff,d2
  1119.  move.w Range,d3
  1120.  sub.w d0,d3
  1121.  muls d3,d1
  1122.  muls d3,d2
  1123.  divs d0,d1
  1124.  divs d0,d2
  1125.  move.w d1,shovex
  1126.  move.w d2,shovez
  1127.  bra nochange
  1128.  
  1129. faraway:
  1130.  move.w speed,d3
  1131.  add.w Range,d3
  1132.  cmp.w d0,d3
  1133.  blt.s .notoofast
  1134.  move.w d0,d3
  1135.  st GotThere
  1136. .notoofast:
  1137.  sub.w Range,d3
  1138.  
  1139.  move.w xdiff,d1
  1140.  muls d3,d1
  1141.  divs d0,d1
  1142.  move.w zdiff,d2
  1143.  muls d3,d2
  1144.  divs d0,d2
  1145.  add.w oldx,d1
  1146.  move.w d1,newx
  1147.  add.w oldz,d2
  1148.  move.w d2,newz
  1149.  
  1150. nochange:
  1151.  
  1152.  rts
  1153.  
  1154.  
  1155. CalcDist:
  1156.  
  1157.  move.w newx,d1
  1158.  sub.w oldx,d1
  1159.  move.w d1,xdiff
  1160.  move.w newz,d2
  1161.  sub.w oldz,d2
  1162.  move.w d2,zdiff
  1163.  muls d1,d1
  1164.  muls d2,d2
  1165.  move.w #0,d0
  1166.  move.w d0,distaway
  1167.  add.l d1,d2
  1168.  beq .nochange
  1169.  
  1170.  move.w #31,d0
  1171. .findhigh
  1172.  btst d0,d2
  1173.  bne .foundhigh
  1174.  dbra d0,.findhigh
  1175. .foundhigh
  1176.  asr.w #1,d0
  1177.  clr.l d3
  1178.  bset d0,d3
  1179.  move.l d3,d0
  1180.  
  1181.  move.w d0,d1
  1182.  muls d1,d1    ; x*x
  1183.  sub.l d2,d1    ; x*x-a
  1184.  asr.l #1,d1    ; (x*x-a)/2
  1185.  divs d0,d1    ; (x*x-a)/2x
  1186.  sub.w d1,d0    ; second approx
  1187.  bgt .stillnot0
  1188.  move.w #1,d0
  1189. .stillnot0
  1190.  
  1191.  move.w d0,d1
  1192.  muls d1,d1
  1193.  sub.l d2,d1
  1194.  asr.l #1,d1
  1195.  divs d0,d1
  1196.  sub.w d1,d0    ; second approx
  1197.  bgt .stillnot02
  1198.  move.w #1,d0
  1199. .stillnot02
  1200.  
  1201.  move.w d0,distaway
  1202. .nochange:
  1203.  
  1204.  rts
  1205.  
  1206.  
  1207. counterer: dc.w 0
  1208. CosRet: dc.w 0
  1209. SinRet: dc.w 0
  1210.  
  1211. HeadTowardsAng:
  1212.  
  1213.  move.w newx,d1
  1214.  sub.w oldx,d1
  1215.  move.w d1,xdiff
  1216.  move.w newz,d2
  1217.  sub.w oldz,d2
  1218.  move.w d2,zdiff
  1219.  muls d1,d1
  1220.  muls d2,d2
  1221.  move.w #0,d0
  1222.  add.l d1,d2
  1223.  seq GotThere
  1224.  beq .nochange
  1225.  
  1226.  move.w #31,d0
  1227. .findhigh
  1228.  btst d0,d2
  1229.  bne .foundhigh
  1230.  dbra d0,.findhigh
  1231. .foundhigh
  1232.  asr.w #1,d0
  1233.  clr.l d3
  1234.  bset d0,d3
  1235.  move.l d3,d0
  1236.  
  1237.  move.w d0,d1
  1238.  muls d1,d1    ; x*x
  1239.  sub.l d2,d1    ; x*x-a
  1240.  asr.l #1,d1    ; (x*x-a)/2
  1241.  divs d0,d1    ; (x*x-a)/2x
  1242.  sub.w d1,d0    ; second approx
  1243.  bgt .stillnot0
  1244.  move.w #1,d0
  1245. .stillnot0
  1246.  
  1247.  move.w d0,d1
  1248.  muls d1,d1
  1249.  sub.l d2,d1
  1250.  asr.l #1,d1
  1251.  divs d0,d1
  1252.  sub.w d1,d0    ; second approx
  1253.  bgt .stillnot02
  1254.  move.w #1,d0
  1255. .stillnot02
  1256.  
  1257.  move.w d0,d1
  1258.  muls d1,d1
  1259.  sub.l d2,d1
  1260.  asr.l #1,d1
  1261.  divs d0,d1
  1262.  sub.w d1,d0    ; second approx
  1263.  bgt .stillnot03
  1264.  move.w #1,d0
  1265. .stillnot03
  1266.  
  1267.  
  1268. ; d0=perpdist
  1269.  
  1270.  cmp.w Range,d0
  1271.  sle GotThere
  1272.  bgt .faraway
  1273.  
  1274.  move.w oldx,newx
  1275.  move.w oldz,newz
  1276.  bra .nochange
  1277.  
  1278.  move.w xdiff,d1
  1279.  move.w zdiff,d2
  1280.  muls Range,d1
  1281.  muls Range,d2
  1282.  addq #3,d0
  1283.  divs d0,d1
  1284.  divs d0,d2
  1285.  subq #3,d0
  1286.  neg.w d1
  1287.  neg.w d2
  1288.  add.w d1,newx
  1289.  add.w d2,newz
  1290.  tst.b canshove
  1291.  beq .nochange
  1292.  move.w PLR1_opushx(pc),d1
  1293.  add.w PLR2_opushx(pc),d1
  1294.  sub.w d1,newx
  1295.  move.w PLR1_opushz(pc),d1
  1296.  add.w PLR2_opushz(pc),d1
  1297.  sub.w d1,newz
  1298.  move.w xdiff,d1
  1299.  move.w zdiff,d2
  1300.  move.w Range,d3
  1301.  sub.w d0,d3
  1302.  muls d3,d1
  1303.  muls d3,d2
  1304.  divs d0,d1
  1305.  divs d0,d2
  1306.  move.w d1,shovex
  1307.  move.w d2,shovez
  1308.  bra .nochange
  1309.  
  1310. .faraway:
  1311.  
  1312.  move.w speed,d3
  1313.  add.w Range,d3
  1314.  cmp.w d0,d3
  1315.  blt.s .notoofast
  1316.  move.w d0,d3
  1317.  st GotThere
  1318. .notoofast:
  1319.  sub.w Range,d3
  1320.  
  1321.  move.w xdiff,d1
  1322.  muls d3,d1
  1323.  divs d0,d1
  1324.  move.w zdiff,d2
  1325.  muls d3,d2
  1326.  divs d0,d2
  1327.  add.w oldx,d1
  1328.  move.w d1,newx
  1329.  add.w oldz,d2
  1330.  move.w d2,newz
  1331.  
  1332. .nochange:
  1333.  
  1334.  tst.w d0
  1335.  beq.s nocossin
  1336.  
  1337.  add.w #1,d0
  1338.  move.w xdiff,d1
  1339.  swap d1
  1340.  clr.w d1
  1341.  asr.l #1,d1
  1342.  divs d0,d1
  1343.  move.w d1,SinRet
  1344.  move.w zdiff,d1
  1345.  swap d1
  1346.  clr.w d1
  1347.  asr.l #1,d1
  1348.  divs d0,d1
  1349.  move.w d1,CosRet
  1350.  
  1351.  move.w SinRet,d0
  1352.  move.w #0,d2
  1353.  move.l #SineTable,a2
  1354.  lea 2048(a2),a3
  1355.  move.w #3,d5
  1356.  move.w #2048,d6
  1357. findanglop:
  1358.  
  1359.  move.w (a2,d2.w*2),d3
  1360.  move.w (a3,d2.w*2),d4
  1361.  muls d0,d4
  1362.  muls d1,d3
  1363.  sub.l d3,d4
  1364.  blt.s subang
  1365.  add.w d6,d2
  1366.  add.w d6,d2
  1367. subang:
  1368.  sub.w d6,d2
  1369.  and.w #4095,d2
  1370.  asr.w #1,d6
  1371.  dbra d5,findanglop
  1372.  add.w d2,d2
  1373.  move.w d2,AngRet
  1374.  
  1375. nocossin:
  1376.  
  1377.  rts
  1378.  
  1379. AngRet: dc.w 0
  1380. Range: dc.w 0
  1381. GotThere: dc.w 0
  1382. shovex: dc.w 0
  1383. shovez: dc.w 0
  1384. canshove: dc.w 0
  1385. PLR2_pushx: dc.l 0
  1386. PLR2_pushz: dc.l 0
  1387. PLR2_opushx: dc.l 0
  1388. PLR2_opushz: dc.l 0
  1389. PLR1_pushx: dc.l 0
  1390. PLR1_pushz: dc.l 0
  1391. PLR1_opushx: dc.l 0
  1392. PLR1_opushz: dc.l 0
  1393.  
  1394. CheckHit:
  1395.  move.w newx,d0
  1396.  sub.w oldx,d0
  1397.  move.w newz,d1
  1398.  sub.w oldz,d1
  1399.  muls d1,d1
  1400.  muls d0,d0
  1401.  add.l d0,d1
  1402.  cmp.l d2,d1
  1403.  slt hitwall
  1404.  rts
  1405.  
  1406. GetNextCPt:
  1407.  cmp.w d0,d1
  1408.  beq.s noneedforhassle
  1409.  muls #100,d0
  1410.  ext.l d1
  1411.  add.l d1,d0
  1412.  move.l a0,-(a7)
  1413.  lea ControlPts,a0
  1414.  move.b (a0,d0.w),d0
  1415.  ext.w d0
  1416.  move.l (a7)+,a0
  1417. noneedforhassle:
  1418.  rts
  1419.  
  1420. FromRoom: dc.l 0
  1421. ToRoom: dc.l 0
  1422. CanSee: dc.w 0
  1423. Facedir: dc.w 0
  1424.  
  1425.  even
  1426.  
  1427. CanItBeSeenAng:
  1428.  movem.l d0-d7/a0-a6,-(a7)
  1429.  
  1430.  move.w Facedir,d0
  1431.  move.l #SineTable,a0
  1432.  add.w d0,a0
  1433.  move.w (a0),d0
  1434.  move.w 2048(a0),d1
  1435.  move.w Targetx,d2
  1436.  sub.w Viewerx,d2
  1437.  move.w Targetz,d3
  1438.  sub.w Viewerz,d3
  1439.  muls d1,d2
  1440.  muls d0,d3
  1441.  sub.l d3,d2
  1442.  bgt.s ItMightBeSeen
  1443.  clr.b CanSee
  1444.  movem.l (a7)+,d0-a7/a0-a6
  1445.  rts
  1446. ItMightBeSeen:
  1447.  
  1448.  move.l ToRoom,a0
  1449.  move.w (a0),d0
  1450.  move.l FromRoom,a0
  1451.  adda.w #ToListOfGraph,a0
  1452.  bra.s InList
  1453.  
  1454. Viewerx: dc.l 0
  1455. Viewerz: dc.l 0
  1456. Targetx: dc.l 0
  1457. Targetz: dc.l 0
  1458. ViewerTop: dc.b 0
  1459. TargetTop: dc.b 0 
  1460. Viewery: dc.w 0
  1461. Targety: dc.w 0
  1462.  
  1463.   even
  1464.  
  1465. insameroom:
  1466.  st CanSee
  1467.  move.b ViewerTop,d0
  1468.  move.b TargetTop,d1
  1469.  eor.b d0,d1
  1470.  bne outlist
  1471.  movem.l (a7)+,d0-d7/a0-a6
  1472.  rts
  1473.  
  1474. CanItBeSeen:
  1475.  
  1476.  movem.l d0-d7/a0-a6,-(a7)
  1477.  move.l ToRoom,a1
  1478.  move.w (a1),d0
  1479.  move.l FromRoom,a0
  1480.  cmp.l a0,a1
  1481.  beq.s insameroom
  1482.  
  1483.  adda.w #ToListOfGraph,a0
  1484.  
  1485. InList:
  1486.  move.w (a0),d1
  1487.  tst.w d1
  1488.  blt outlist
  1489.  move.l ZoneGraphAdds,a1
  1490.  move.l (a1,d1.w*8),a1
  1491.  add.l LEVELGRAPHICS,a1
  1492.  
  1493.  adda.w #8,a0
  1494.  cmp.w (a1),d0
  1495.  beq isinlist
  1496.  
  1497.  bra.s InList
  1498.  
  1499. isinlist:
  1500. ; We have found the dest room in the
  1501. ; list of rooms visible from the
  1502. ; source room.
  1503.  
  1504. ; Do line of sight!
  1505.  
  1506.  st CanSee
  1507.  
  1508.  move.l Points,a2
  1509.  move.w Targetx,d1
  1510.  move.w Targetz,d2
  1511.  sub.w Viewerx,d1
  1512.  sub.w Viewerz,d2
  1513.  
  1514.  moveq #0,d3
  1515.  move.w -6(a0),d3
  1516.  blt nomorerclips
  1517.  move.l LEVELCLIPS,a1
  1518.  lea (a1,d3.l*2),a1
  1519.  move.l a1,clipstocheck
  1520. checklcliploop:
  1521.  tst.w (a1)
  1522.  blt nomorelclips
  1523.  
  1524.  move.w (a1),d0
  1525.  blt.s noleftone
  1526.  move.l (a2,d0.w*4),d3
  1527.  move.w d3,d4
  1528.  sub.w Viewerz,d4
  1529.  swap d3
  1530.  sub.w Viewerx,d3
  1531.  muls d2,d3
  1532.  muls d1,d4
  1533.  sub.l d3,d4
  1534.  ble outlist
  1535.  
  1536. noleftone:
  1537.  
  1538.  addq #2,a1
  1539.  
  1540.  bra checklcliploop
  1541.  
  1542. nomorelclips:
  1543.  
  1544.  addq #2,a1
  1545.  
  1546. checkrcliploop:
  1547.  tst.w (a1)
  1548.  blt nomorerclips
  1549.  
  1550.  move.w (a1),d0
  1551.  blt.s norightone
  1552.  move.l (a2,d0.w*4),d3
  1553.  move.w d3,d4
  1554.  sub.w Viewerz,d4
  1555.  swap d3
  1556.  sub.w Viewerx,d3
  1557.  muls d2,d3
  1558.  muls d1,d4
  1559.  sub.l d3,d4
  1560.  bge outlist
  1561.  
  1562. norightone:
  1563.  addq #2,a1
  1564.  
  1565.  bra checkrcliploop
  1566.  
  1567.  
  1568. nomorerclips:
  1569.  
  1570. ; No clipping points in the way; got to do the
  1571. ; vertical working out now.
  1572.  
  1573.  move.w Targetx,d0
  1574.  move.w Targetz,d1
  1575.  sub.w Viewerx,d0
  1576.  sub.w Viewerz,d1
  1577.  move.l FromRoom,a5
  1578.  move.l FloorLines,a1
  1579.  move.b ViewerTop,d2
  1580.  move.w Targety,d7
  1581.  sub.w Viewery,d7
  1582.  
  1583.  
  1584. GoThroughZones:
  1585.  move.l a5,a0
  1586.  adda.w ToExitList(a0),a0
  1587.  
  1588. FindWayOut:
  1589.  move.w (a0)+,d5
  1590.  blt outlist
  1591.  asl.w #4,d5
  1592.  lea (a1,d5.w),a2
  1593.  
  1594.  move.w (a2),d3
  1595.  move.w 2(a2),d4
  1596.  sub.w Viewerx,d3
  1597.  sub.w Viewerz,d4
  1598.  move.w d3,d5
  1599.  move.w d4,d6
  1600.  muls d1,d3
  1601.  muls d0,d4
  1602.  sub.l d3,d4
  1603.  ble FindWayOut
  1604.  
  1605.  add.w 4(a2),d5
  1606.  add.w 6(a2),d6
  1607.  muls d0,d6
  1608.  muls d1,d5
  1609.  sub.l d5,d6
  1610.  bge FindWayOut
  1611.  
  1612.  tst.w 8(a2)
  1613.  blt outlist
  1614.  
  1615. ; Here is the exit from the room. Calculate the height at which
  1616. ; we meet it.
  1617.  
  1618.  move.w Targetx,d3
  1619.  move.w Targetz,d4
  1620.  sub.w (a2),d3
  1621.  sub.w 2(a2),d4
  1622.  muls 4(a2),d4
  1623.  muls 6(a2),d3
  1624.  sub.l d3,d4    ; positive
  1625.  
  1626.  move.w Viewerx,d5
  1627.  move.w Viewerz,d6
  1628.  sub.w (a2),d5
  1629.  sub.w 2(a2),d6
  1630.  muls 4(a2),d6
  1631.  muls 6(a2),d5
  1632.  sub.l d6,d5    ; positive
  1633.  
  1634.  divs 10(a2),d4
  1635.  divs 10(a2),d5
  1636.  
  1637.  add.w d5,d4
  1638.  beq.s sameheight
  1639.  muls d7,d5
  1640.  divs d4,d5
  1641. sameheight:
  1642.  add.w Viewery,d5    ; height at which we cross wall
  1643.  
  1644.  ext.l d5
  1645.  asl.l #7,d5
  1646.  
  1647.  tst.b d2
  1648.  beq.s comparewithbottom
  1649.  
  1650.  cmp.l ToUpperRoof(a5),d5
  1651.  blt outlist
  1652.  cmp.l ToUpperFloor(a5),d5
  1653.  bgt outlist
  1654.  bra.s madeit
  1655.  
  1656. comparewithbottom:
  1657.  cmp.l ToZoneRoof(a5),d5
  1658.  blt outlist
  1659.  cmp.l ToZoneFloor(a5),d5
  1660.  bgt outlist
  1661. madeit:
  1662.  st donessomething
  1663.  
  1664.  moveq #0,d3
  1665.  move.w 8(a2),d3
  1666.  move.l ZoneAdds,a3
  1667.  move.l (a3,d3.w*4),a5
  1668.  add.l LEVELDATA,a5
  1669.  
  1670.  clr.b d2
  1671.  cmp.l ToZoneFloor(a5),d5
  1672.  bgt outlist
  1673.  cmp.l ToZoneRoof(a5),d5
  1674.  bgt.s GotIn
  1675.  st d2
  1676.  cmp.l ToUpperFloor(a5),d5
  1677.  bgt outlist
  1678.  cmp.l ToUpperRoof(a5),d5
  1679.  blt outlist
  1680.  
  1681. GotIn:
  1682.  
  1683.  cmp.l ToRoom,a5
  1684.  bne GoThroughZones
  1685.  
  1686.  move.b TargetTop,d3
  1687.  eor.b d2,d3
  1688.  bne outlist
  1689.  
  1690.  movem.l (a7)+,d0-d7/a0-a6
  1691.  rts
  1692.  
  1693. clipstocheck: dc.l 0
  1694. donessomething: dc.w 0
  1695.  
  1696. outlist:
  1697.  clr.b CanSee
  1698.  movem.l (a7)+,d0-d7/a0-a6
  1699.  rts
  1700.  
  1701.  
  1702. FindCollisionPt:
  1703.  movem.l d0-a7/a0-a6,-(a7)
  1704.  
  1705.  move.w Targetx,d0
  1706.  move.w Targetz,d1
  1707.  sub.w Viewerx,d0
  1708.  sub.w Viewerz,d1
  1709.  move.l FromRoom,a5
  1710.  move.l FloorLines,a1
  1711.  move.b ViewerTop,d2
  1712.  move.w Targety,d7
  1713.  sub.w Viewery,d7
  1714.  
  1715.  
  1716. .GoThroughZones:
  1717.  move.l a5,a0
  1718.  adda.w ToExitList(a0),a0
  1719.  
  1720. .FindWayOut:
  1721.  move.w (a0)+,d5
  1722.  blt outlist
  1723.  asl.w #4,d5
  1724.  lea (a1,d5.w),a2
  1725.  
  1726.  move.w (a2),d3
  1727.  move.w 2(a2),d4
  1728.  sub.w Viewerx,d3
  1729.  sub.w Viewerz,d4
  1730.  move.w d3,d5
  1731.  move.w d4,d6
  1732.  muls d1,d3
  1733.  muls d0,d4
  1734.  sub.l d3,d4
  1735.  ble .FindWayOut
  1736.  
  1737.  add.w 4(a2),d5
  1738.  add.w 6(a2),d6
  1739.  muls d0,d6
  1740.  muls d1,d5
  1741.  sub.l d5,d6
  1742.  bge .FindWayOut
  1743.  
  1744.  
  1745. ; Here is the exit from the room. Calculate the height at which
  1746. ; we meet it.
  1747.  
  1748.  move.w Targetx,d3
  1749.  move.w Targetz,d4
  1750.  sub.w (a2),d3
  1751.  sub.w 2(a2),d4
  1752.  muls 4(a2),d4
  1753.  muls 6(a2),d3
  1754.  sub.l d3,d4    ; positive
  1755.  
  1756.  move.w Viewerx,d5
  1757.  move.w Viewerz,d6
  1758.  sub.w (a2),d5
  1759.  sub.w 2(a2),d6
  1760.  muls 4(a2),d6
  1761.  muls 6(a2),d5
  1762.  sub.l d6,d5    ; positive
  1763.  
  1764.  divs 10(a2),d4
  1765.  divs 10(a2),d5
  1766.  
  1767.  move.w d5,d6
  1768.  add.w d5,d4
  1769.  beq.s .sameheight
  1770.  muls d7,d5
  1771.  divs d4,d5
  1772. .sameheight:
  1773.  add.w Viewery,d5    ; height at which we cross wall
  1774.  
  1775.  ext.l d5
  1776.  asl.l #7,d5
  1777.  
  1778.  moveq #0,d3
  1779.  move.w 8(a2),d3
  1780.  blt foundpt
  1781.  move.l ZoneAdds,a3
  1782.  move.l (a3,d3.w*4),a5
  1783.  add.l LEVELDATA,a5
  1784.  
  1785.  clr.b d2
  1786.  cmp.l ToZoneFloor(a5),d5
  1787.  bgt foundpt
  1788.  cmp.l ToZoneRoof(a5),d5
  1789.  bgt.s .GotIn
  1790.  st d2
  1791.  cmp.l ToUpperFloor(a5),d5
  1792.  bgt foundpt
  1793.  cmp.l ToUpperRoof(a5),d5
  1794.  blt foundpt
  1795.  
  1796. .GotIn:
  1797.  
  1798.  bra .GoThroughZones
  1799.  
  1800.  tst.w d4
  1801.  beq.s foundpt
  1802.  muls d6,d0
  1803.  divs d4,d0
  1804.  muls d6,d1
  1805.  divs d4,d1
  1806.  add.w Viewerx,d0
  1807.  add.w Viewerz,d1
  1808.  move.w d0,Targetx
  1809.  move.w d1,Targetz
  1810.  move.l d5,Targety
  1811.  
  1812. foundpt:
  1813.  
  1814.  movem.l (a7)+,d0-a7/a0-a6
  1815.  rts
  1816.  
  1817. GetRand:
  1818.  move.w Rand1,d0
  1819.  add.w #29,d0
  1820.  eor.w #$5f37,d0
  1821.  neg.w d0
  1822.  rol.w #5,d0
  1823.  move.w d0,Rand1
  1824.  rts
  1825.  
  1826. Rand1: dc.w 234
  1827.  
  1828. GoInDirection:
  1829.  move.l #SineTable,a0
  1830.  lea (a0,d0.w),a0
  1831.  move.w (a0),d1
  1832.  move.w 2048(a0),d2
  1833.  muls speed,d1
  1834.  add.l d1,d1
  1835.  muls speed,d2
  1836.  add.l d2,d2
  1837.  swap d1
  1838.  swap d2
  1839.  add.w oldx,d1
  1840.  add.w oldz,d2
  1841.  move.w d1,newx
  1842.  move.w d2,newz
  1843.  rts
  1844.  
  1845. CollideFlags: dc.l 0
  1846.  
  1847. Collision:
  1848.  
  1849.  move.l ObjectData,a0
  1850.  move.w CollId,d0
  1851.  asl.w #6,d0
  1852.  move.b 16(a0,d0.w),d0
  1853.  ext.w d0
  1854.  
  1855.  sub.w #64,a0
  1856.  move.l ObjectPoints,a1
  1857.  move.l #ColBoxTable,a2
  1858.  lea  (a2,d0.w*8),a3
  1859.  
  1860.  move.l CollideFlags,d7
  1861.  move.b StoodInTop,d6
  1862.  move.l newy,d4
  1863.  move.l d4,d5
  1864.  add.l thingheight,d5
  1865.  asr.l #7,d4
  1866.  asr.l #7,d5
  1867.  clr.b hitwall
  1868.  
  1869. checkcol:
  1870.  add.w #64,a0
  1871.  
  1872.  move.w (a0),d0
  1873.  blt checkedallcol
  1874.  
  1875.  cmp.w CollId,d0
  1876.  beq.s checkcol
  1877.  
  1878.  tst.w 12(a0)
  1879.  blt.s checkcol
  1880.  
  1881.  tst.b numlives(a0)
  1882.  beq.s checkcol
  1883.  
  1884.  move.b ObjInTop(a0),d1
  1885.  eor.b d6,d1
  1886.  bne checkcol
  1887.  
  1888.  moveq #0,d3
  1889.  move.b 16(a0),d3
  1890.  blt checkcol
  1891.  
  1892.  btst d3,d7
  1893.  beq checkcol
  1894.  
  1895.  move.w 4(a0),d1
  1896.  sub.w 2(a2,d3.w*8),d1
  1897.  cmp.w d1,d5
  1898.  blt checkcol
  1899.  add.w 4(a2,d3.w*8),d1
  1900.  cmp.w d1,d4
  1901.  bgt checkcol
  1902.  
  1903.  move.w (a1,d0.w*8),d1
  1904.  move.w 4(a1,d0.w*8),d2
  1905.  sub.w newx,d1
  1906.  bge.s .xnoneg
  1907.  neg.w d1
  1908. .xnoneg:
  1909.  sub.w newz,d2
  1910.  bge.s .znoneg
  1911.  neg.w d2
  1912. .znoneg:
  1913.  cmp.w d1,d2
  1914.  ble.s .checkx
  1915.  sub.w (a3),d2
  1916.  cmp.w (a2,d3.w*8),d2
  1917.  bgt checkcol
  1918.  st hitwall
  1919.  bra checkedallcol
  1920. .checkx:
  1921.  sub.w (a3),d1
  1922.  cmp.w (a2,d3.w*8),d1
  1923.  bgt checkcol
  1924.  
  1925.  move.w (a1,d0.w*8),d1
  1926.  move.w 4(a1,d0.w*8),d2
  1927.  move.w d1,d6
  1928.  move.w d2,d7
  1929.  sub.w newx,d6
  1930.  sub.w newz,d7
  1931.  muls d6,d6
  1932.  muls d7,d7
  1933.  add.l d6,d7
  1934.  sub.w oldx,d1
  1935.  sub.w oldz,d2
  1936.  muls d1,d1
  1937.  muls d2,d2
  1938.  add.l d1,d2
  1939.  cmp.l d2,d7
  1940.  bgt checkcol
  1941.  
  1942.  st hitwall
  1943.  bra checkedallcol
  1944.  
  1945. ; bra checkcol
  1946.  
  1947. checkedallcol:
  1948.  rts
  1949.  
  1950. ColBoxTable:
  1951.  
  1952. ; red scurrying alien
  1953.  dc.w 40,60,120,0
  1954. ; Medipack
  1955.  dc.w 40,20,40,0
  1956. ; Bullet
  1957.  dc.w 40,20,40,0
  1958. ; Gun
  1959.  dc.w 40,20,40,0
  1960. ; Key
  1961.  dc.w 40,20,40,0
  1962. ; PLayer1
  1963.  dc.w 40,40,80,0
  1964. ;Robot
  1965.  dc.w 40,50,100,0
  1966. ;?
  1967.  dc.w 40,20,40,0
  1968. ; Flying Nasty
  1969.  dc.w 80,60,120,0
  1970. ; Ammo
  1971.  dc.w 40,20,40,0
  1972. ; Barrel
  1973.  dc.w 40,30,60,0
  1974. ;PlAYER2
  1975.  dc.w 40,40,80,0
  1976. ; Mutant Marine
  1977.  dc.w 40,40,80,0
  1978. ; worm
  1979.  dc.w 80,60,120,0
  1980. ; huge red thing
  1981.  dc.w 160,100,200,0
  1982. ; small red thing
  1983.  dc.w 80,50,100,0
  1984. ; tree
  1985.  dc.w 80,60,120,0
  1986. ; eyeball
  1987.  dc.w 40,30,60,0
  1988. ; Tough Marine
  1989.  dc.w 40,40,80,0
  1990. ; ShotGun Marine
  1991.  dc.w 40,40,80,0
  1992.  
  1993. FromZone: dc.w 0
  1994. OKTEL: dc.w 0
  1995. floortemp: dc.l 0
  1996.  
  1997. CheckTeleport:
  1998.  clr.b OKTEL
  1999.  move.w FromZone,d0
  2000.  move.l ZoneAdds,a2
  2001.  move.l (a2,d0.w*4),a2
  2002.  add.l LEVELDATA,a2
  2003.  tst.w ToTelZone(a2)
  2004.  bge.s ITSATEL
  2005.  rts
  2006.  
  2007. ITSATEL:
  2008.  move.l ToZoneFloor(a2),floortemp
  2009.  move.w ToTelZone(a2),d0
  2010.  move.l ZoneAdds,a3
  2011.  move.l (a3,d0.w*4),a3
  2012.  add.l LEVELDATA,a3
  2013.  move.l ToZoneFloor(a3),d0
  2014.  sub.l floortemp,d0
  2015.  move.l d0,floortemp
  2016.  add.l d0,newy 
  2017.  move.w ToTelX(a2),newx
  2018.  move.w ToTelZ(a2),newz
  2019.  move.l #%1111111111111111111,CollideFlags
  2020.  movem.l a0/a1/a2,-(a7)
  2021.  bsr Collision
  2022.  movem.l (a7)+,a0/a1/a2
  2023.  
  2024.  move.l floortemp,d0
  2025.  sub.l d0,newy
  2026.  
  2027.  tst.b hitwall
  2028.  seq OKTEL
  2029.  beq.s .teleport
  2030.  rts
  2031. .teleport:
  2032.  move.w ToTelZone(a2),d0
  2033.  move.l ZoneAdds,a2
  2034.  move.l (a2,d0.w*4),a2
  2035.  add.l LEVELDATA,a2
  2036.  move.l a2,objroom
  2037.  
  2038.  rts
  2039.  
  2040. FindCloseRoom:
  2041.  ; d0 is distance.
  2042.  
  2043.  move.w 4(a0),d1
  2044.  ext.l d1
  2045.  asl.l #7,d1
  2046.  move.l d1,oldy
  2047.  move.l d1,newy
  2048.  
  2049.  move.w (a0),d1
  2050.  move.l ObjectPoints,a1
  2051.  lea (a1,d1.w*8),a1
  2052.  move.w (a1),oldx 
  2053.  move.w 4(a1),oldz
  2054.  
  2055.  move.w 12(a0),d2
  2056.  move.l ZoneAdds,a5
  2057.  move.l (a5,d2.w*4),d2
  2058.  add.l LEVELDATA,d2
  2059.  move.l d2,objroom
  2060.  
  2061.  move.w THISPLRxoff,newx
  2062.  move.w THISPLRzoff,newz
  2063.  move.w d0,speed
  2064.  movem.l a0/a1,-(a7)
  2065.  jsr HeadTowards
  2066.  movem.l (a7)+,a0/a1
  2067.  
  2068.  move.w newx,d0
  2069.  sub.w oldx,d0
  2070.  move.w oldz,d1
  2071.  sub.w newz,d1
  2072.  
  2073.  move.w d1,xd
  2074.  move.w d0,zd
  2075.  
  2076.  move.l #100000,StepUpVal
  2077.  move.l #100000,StepDownVal
  2078.  move.w #0,thingheight
  2079.  
  2080.  st exitfirst
  2081.  
  2082.  add.w oldx,d1
  2083.  add.w oldz,d0
  2084.  move.w d1,newx
  2085.  move.w d0,newz
  2086.  movem.l d0-d7/a0-a6,-(a7)
  2087.  jsr MoveObject
  2088.  movem.l (a7)+,d0-d7/a0-a6
  2089.  
  2090.  move.l #RoomPath,a2
  2091.  move.l #possclose,a3
  2092.  move.w 12(a0),(a3)+
  2093.  
  2094. putinmore:
  2095.  move.w (a2)+,(a3)+
  2096.  bge.s putinmore
  2097.  subq #2,a3
  2098.  
  2099.  move.w oldx,d0
  2100.  sub.w xd,d0
  2101.  move.w oldz,d1
  2102.  sub.w zd,d1
  2103.  move.w d0,newx
  2104.  move.w d1,newz    
  2105.  
  2106.  movem.l d0-d7/a0-a6,-(a7)
  2107.  jsr MoveObject
  2108.  movem.l (a7)+,d0-d7/a0-a6
  2109.  
  2110.  move.l #RoomPath,a2
  2111.  
  2112. putinmore2:
  2113.  move.w (a2)+,d0
  2114.  move.w d0,(a3)+
  2115.  tst.w d0
  2116.  bge.s putinmore2
  2117.  
  2118. ; ok a3 points at list of rooms passed through.
  2119.  move.w #-1,(a3)+
  2120.  
  2121.  
  2122.  move.w 12(a0),d7
  2123.  
  2124.  move.l endoflist,a3
  2125. FINDCLOSELOOP:
  2126.  move.l #possclose,a2
  2127.  move.w -(a3),d0
  2128.  blt foundclose
  2129.  
  2130. findinner
  2131.  move.w (a2)+,d1
  2132.  blt.s outin
  2133.  cmp.w d0,d1
  2134.  bne.s findinner
  2135.  move.w d0,d7
  2136. outin:
  2137.  
  2138.  bra.s FINDCLOSELOOP
  2139.  
  2140. foundclose:
  2141.  
  2142.  move.w d7,GraphicRoom(a0)
  2143.  
  2144.  rts
  2145.  
  2146. xd: dc.w 0
  2147. zd: dc.w 0
  2148.  
  2149. possclose:
  2150.  ds.w 100